popup mlv

作ったり、買ったり、遊んだり。

ESP32(Arduino)でEOS Kiss M (M50)にBluetoothで接続して撮影してみた

f:id:popupin0x0:20200507004336j:plain

ESP32(Arduino)でEOS Kiss M (M50)にBluetoothで接続して撮影してみた話です。

実は以前同じネタをしたのですが、不具合を隠していました。できたように見せかけていたのです。黙っていたのですが質問が飛んできたときによぎったのでできる限り完成に近づけることにします。

popupmlv.hatenablog.com

コードの解説と動作

Arduino IDEを使って作っています。ESP32の1.0.4動くことを確認しています。このコードの元はスケッチ例「ESP32 BLE Arduino → BLE_Client.ino」にほぼ同じもので書かれています。

github.com

f:id:popupin0x0:20200507004546j:plain

「addrCanonEOS」にカメラのBluetoothMACアドレスを入力してください。ペアリングしたらそのままシャッターを切り続けます。事前にドライブモードを「セルフタイマー10秒」に設定しておきます。これがないとリモコンが使えません。カメラを再起動すると再度ペアリングする必要があります。ここは再接続の仕方がわからないためです。ですが今では重大な問題ではないのでこのままにしておきます。ESP32は再起動しても接続できます。

f:id:popupin0x0:20200507004523j:plain

ESP32を再起動させる理由は「onDisconnect」になるためです。これになぜなるのかと言うと単純にdelayが足りないためです。ここでは400msecとしていますが200msecでもだいたいうまくいきます。これともう一つあり、特定するのも面倒なのでやめましたがどこかで止まります。電波を飛ばすとき、シャッターを切る時などはとにかく遅延を入れないとよく失敗します。

シャッターを切った後にカメラが操作を受け付けなくなるので{MODE_IMMEDIATE}を書き込んで操作できるようにします。コレがなくてもシャッターに影響はありませんがカメラの電源をオフにするかESP32をリセット以外方法はありません。カメラがスリープモードになる時間を設定していなくとも約2分を超えると完全にペアリングが切れます。2回目以降は1分ほどで切断されるので定期的にシャッターの操作をする必要があります。

ESP32を再起動させるのでこれ1つで完結しようとするとEEPROMにデータを保存したりする必要があります。再接続ができませんがわからないのでこのままにしておくとして完成です。Androidだとたぶん「BluetoothGatt.connect()」で解決することなので複雑なことはやってなさそうなのですがわかりません。

ESP32以外でもできると思いますがESP32のやすさを考えるとやめたほうがいいです。何よりサンプルの出来が非常にいいです。

ja.aliexpress.com

コード

/**
 * 
 * BLE ESP32 Arduino 内の BLE_client.ino を使用したもの
 * EOS Kiss Mと接続してシャッターを切る
 * 
 * 
 * 問題は本体を再起動するともう一度ペアリングしなければ使えない
 * 
 * 
 */

#include "BLEDevice.h"
//#include "BLEScan.h"

// カメラに表示する名前
String DEVICE_NAME = "ESP32";
// モード+ボタンの組み合わせ
byte BUTTON_RELEASE = 0b10000000;
byte BUTTON_FOCUS   = 0b01000000;
byte BUTTON_TELE    = 0b00100000;
byte BUTTON_WIDE    = 0b00010000;
byte MODE_IMMEDIATE = 0b00001100;
byte MODE_DELAY     = 0b00000100;
byte MODE_MOVIE     = 0b00001000;

// My Canon EOS MAC Address
static String addrCanonEOS = "xx:xx:xx:xx:xx:xx";
// CANON_BLUETOOTH_REMOTE_SERVICE serviceUUID
static BLEUUID serviceUUID("00050000-0000-1000-0000-d8492fffa821");
// The characteristic of the remote service we are interested in. charUUID
static BLEUUID CANON_PAIRING_SERVICE("00050002-0000-1000-0000-d8492fffa821");
// The characteristic of the remote service we are interested in. charUUID
static BLEUUID CANON_SHUTTER_CONTROL_SERVICE("00050003-0000-1000-0000-d8492fffa821");

static boolean doConnect = false;
static boolean connected = false;
static boolean doScan = false;
static BLERemoteCharacteristic* pRemoteCharacteristic;
static BLEAdvertisedDevice* myDevice;

static void notifyCallback(
  BLERemoteCharacteristic* pBLERemoteCharacteristic,
  uint8_t* pData,
  size_t length,
  bool isNotify) {
    Serial.print("Notify callback for characteristic ");
    Serial.print(pBLERemoteCharacteristic->getUUID().toString().c_str());
    Serial.print(" of data length ");
    Serial.println(length);
    Serial.print("data: ");
    Serial.println((char*)pData);
}

class MyClientCallback : public BLEClientCallbacks {
  void onConnect(BLEClient* pclient) {
  }

  void onDisconnect(BLEClient* pclient) {
    connected = false;
    Serial.println("onDisconnect");
    // scanからclientに接続するまでが400msec未満だと接続に失敗しやすくなる 何もできなくなるのでESP32を再起動
    esp_restart();
  }
};


/**
 * Scan for BLE servers and find the first one that advertises the service we are looking for.
 */
class MyAdvertisedDeviceCallbacks: public BLEAdvertisedDeviceCallbacks {
 /**
   * Called for each advertising BLE server.
   */
  void onResult(BLEAdvertisedDevice advertisedDevice) {
    Serial.print("BLE Advertised Device found: ");
    Serial.println(advertisedDevice.toString().c_str());

    // We have found a device, let us now see if it contains the service we are looking for.
    String addr = advertisedDevice.getAddress().toString().c_str();
    if (addr.equalsIgnoreCase(addrCanonEOS)) {
      BLEDevice::getScan()->stop();
      myDevice = new BLEAdvertisedDevice(advertisedDevice);
      doConnect = true;
      doScan = true;

    } // Found our server
  } // onResult
}; // MyAdvertisedDeviceCallbacks


void setup() {
  Serial.begin(115200);
  Serial.println("Starting Arduino BLE Client application...");
  BLEDevice::init("");

  // Retrieve a Scanner and set the callback we want to use to be informed when we
  // have detected a new device.  Specify that we want active scanning and start the
  // scan to run for 5 seconds.
  BLEScan* pBLEScan = BLEDevice::getScan();
  pBLEScan->setAdvertisedDeviceCallbacks(new MyAdvertisedDeviceCallbacks());
  pBLEScan->setInterval(1349);
  pBLEScan->setWindow(449);
  pBLEScan->setActiveScan(true);
  pBLEScan->start(5, false);
} // End of setup.


// This is the Arduino main loop function.
void loop() {
  // If the flag "doConnect" is true then we have scanned for and found the desired
  // BLE Server with which we wish to connect.  Now we connect to it.  Once we are 
  // connected we set the connected flag to be true.
  if (doConnect == true) {
    if (pairAndConnect()) {
      Serial.println("We are now connected to the BLE Server.");
    } else {
      Serial.println("We have failed to connect to the server; there is nothin more we will do.");
    }
    doConnect = false;
  }

  // If we are connected to a peer BLE Server, update the characteristic each time we are reached
  // with the current time since boot.
  if (connected) {
    // シャッターを切る
    connectAndShatter();
  }else if(doScan){
    BLEDevice::getScan()->start(0);  // this is just eample to start scan after disconnect, most likely there is better way to do it in arduino
  }
  
  delay(5000); // Delay a second between loops.
  esp_restart();
} // End of loop


bool connectAndShatter() {
  // カメラのシャッターを切るコマンドを送る
  Serial.print("Forming a connection to ");
  Serial.println(myDevice->getAddress().toString().c_str());
  
  BLEClient*  pClient  = BLEDevice::createClient();
  Serial.println(" - Created client");

  pClient->setClientCallbacks(new MyClientCallback());

  // Connect to the remove BLE Server. 
  // 遅延がないとよく接続に失敗する
  delay(400);
  pClient->connect(myDevice);  // if you pass BLEAdvertisedDevice instead of address, it will be recognized type of peer device address (public or private)
  Serial.println(" - Connected to server");

  // Obtain a reference to the service we are after in the remote BLE server.
  BLERemoteService* pRemoteService = pClient->getService(serviceUUID);
  if (pRemoteService == nullptr) {
    Serial.print("Failed to find our service UUID: ");
    Serial.println(serviceUUID.toString().c_str());
    pClient->disconnect();
    return false;
  }
  Serial.println(" - Found our service");


  // Obtain a reference to the characteristic in the service of the remote BLE server.
  pRemoteCharacteristic = pRemoteService->getCharacteristic(CANON_SHUTTER_CONTROL_SERVICE);
  if (pRemoteCharacteristic == nullptr) {
    Serial.print("Failed to find our characteristic UUID: ");
    Serial.println(CANON_SHUTTER_CONTROL_SERVICE.toString().c_str());
    pClient->disconnect();
    return false;
  }
  Serial.println(" - Found our characteristic");

  // Read the value of the characteristic.
  if(pRemoteCharacteristic->canRead()) {
    std::string value = pRemoteCharacteristic->readValue();
    Serial.print("The characteristic value was: ");
    Serial.println(value.c_str());
  }

  if(pRemoteCharacteristic->canNotify())
    pRemoteCharacteristic->registerForNotify(notifyCallback);

  // シャッターコマンドを書き込む
  byte value[] = {MODE_IMMEDIATE|BUTTON_RELEASE};
  pRemoteCharacteristic->writeValue(value, sizeof(value), false);
  // ある程度遅延を入れて無意味なコマンドを送ると操作できるようになる
  // または、長時間のインターバル撮影をするときに接続を維持するのにも使える
  // シャッターを切った後から遅延が短いと失敗する
  delay(1000);
  byte value2[] = {MODE_IMMEDIATE};
  pRemoteCharacteristic->writeValue(value2, sizeof(value2), false);
  connected = true;
  return true;
}


bool pairAndConnect() {
  // カメラとペアリングする
  Serial.print("Forming a connection to ");
  Serial.println(myDevice->getAddress().toString().c_str());
  
  BLEClient*  pClient  = BLEDevice::createClient();
  Serial.println(" - Created client");

  pClient->setClientCallbacks(new MyClientCallback());

  // Connect to the remove BLE Server.
  delay(400);
  pClient->connect(myDevice);  // if you pass BLEAdvertisedDevice instead of address, it will be recognized type of peer device address (public or private)
  Serial.println(" - Connected to server");

  // Obtain a reference to the service we are after in the remote BLE server.
  BLERemoteService* pRemoteService = pClient->getService(serviceUUID);
  if (pRemoteService == nullptr) {
    Serial.print("Failed to find our service UUID: ");
    Serial.println(serviceUUID.toString().c_str());
    pClient->disconnect();
    return false;
  }
  Serial.println(" - Found our service");


  // Obtain a reference to the characteristic in the service of the remote BLE server.
  pRemoteCharacteristic = pRemoteService->getCharacteristic(CANON_PAIRING_SERVICE);
  if (pRemoteCharacteristic == nullptr) {
    Serial.print("Failed to find our characteristic UUID: ");
    Serial.println(CANON_PAIRING_SERVICE.toString().c_str());
    pClient->disconnect();
    return false;
  }
  Serial.println(" - Found our characteristic");

  // Read the value of the characteristic.
  if(pRemoteCharacteristic->canRead()) {
    std::string value = pRemoteCharacteristic->readValue();
    Serial.print("The characteristic value was: ");
    Serial.println(value.c_str());
  }

  if(pRemoteCharacteristic->canNotify())
    pRemoteCharacteristic->registerForNotify(notifyCallback);

  // キャラクタリスティックにペアリングコマンドを書き込む
  // 先頭はペアリングコマンドに書き換え、末尾は切れるので追加
  String ctlchar_name = "0" + DEVICE_NAME + "0";
  byte value[ctlchar_name.length()];
  ctlchar_name.getBytes(value, ctlchar_name.length());
  value[0] = {0x03};
  value[-1] = {0x00};
  pRemoteCharacteristic->writeValue(value, sizeof(value), false);

  connected = true;
  return true;
}

参考

Reverse engineering the Canon t7i's bluetooth (work in progress)

GitHub - iebyt/cbremote

DSAS開発者の部屋:SwitchBot を ESP32 で遠隔操作してみた